Text File Search
Text File Search
Applications often report on their status by writing to log files. These log files contain a wealth of information and can be used by system administrators to determine the health of a computing system. Searching these log files manually would take hours, if not days. VBScript offers the Scripting.FileSystemObject, which can be used to perform a programmatic text file search for certain string. For example, if an administrator runs across a text file which contains 5000 lines of text and she wants to search for the term “failed”, it would take her quite some time to find that term if it even exists. It may exist in the log file several times as well. If she were to write a script as shown below using VBScript, this process can go from taking hours to minutes or seconds, vastly improving her productivity.
VBScript Code
Text File
Create a Text File to Search
Setup a simple test file first. Open Notepad by going to Start-->All Programs-->Accessories-->Notepad. Within Notepad, go to File-->Save As and save the file to C:\Temp\textfile.txt. In the newly created text file, type “test1”, then press “enter”, “test2”, press “enter”, “test3”, press “enter” and on to “test 5”. The file should look like the picture on the right. Save this file by going to File-->Save. Close the textfile.txt file. This file will be used as the file to be searched by the VBScript that will be created below.
Create VBScript
Open Notepad by going to Start-->All Program-->Accessories-->Notepad. Within Notepad, go to File-->Save As and save the file to C:\Temp\ searchTxtFile.vbs. Adding the “.vbs” file extension makes the text file a VBScript executable. Copy the following code into the searchTxtFile.vbs file. Within the code, there are comments, which start with “’”. These comments explain what the code is doing.
Start copy on line below.
Option Explicit
'Define the location of the text file to read and set it to a variable named txttoread.
Const txttoread = "C:\temp\textfile.txt"
'Declare Variables
Public objFSO
Public wshShell
Public objReadFile
Dim strLine
Dim count
'Set Objects
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set wshShell = CreateObject( "WScript.Shell" )
'Opens text file to read only.
Set objReadFile = objFSO.OpenTextFile(txttoread, 1, False)
'The count variable will be used to count the number of times the "test3" string is found.
'It will be set to "0" initially.
count = 0
'Loops through each line until it reaches the end of the text file.
Do Until objReadFile.AtEndOfStream
strLine = objReadFile.ReadLine
'If "test3" is found in the text file, count will no longer = "0"
'and a message will appear.
If instr(strLine, "test3") Then
count = count + 1
End If
Loop
'Display message to user on the number of times "test3" was found.
If count = 0 Then
wscript.echo "test3 was not found!"
Else
wscript.echo "Number of times test3 was found: " & count
End If
'close text file
objReadFile.close
'Clean up objects from memory
Set objFSO = nothing
Set wshShell = nothing
Stop copy on line above.
VBScript Messagebox
Run VBScript and Test the Text file Search
Test VBScript by browsing to C:\Temp\ searchTxtFile.vbs and double clicking on the searshTxtFile.vbs script. A messagebox should pop up stating that test3 was found with a number indicating how many times it was found.Browse to the C:\temp\textfile.txt file and double click on it. Delete the “test3” line and save the file. Double click on the searchTxtFile.vbs file again. A different messagebox should appear stating that test3 was not found.
Experiment with the textfile.txt by adding several more lines that include the string “test3”. Save the file and run the searchTxtFile.vbs file again. Make note of the number of times test3 is found in the messagebox that appears. Experimentation with the VBScript and text file should give the user an idea of how valuable searching a text file can be.
